//
// Standard with reflection cubemap
//

#include "atmosphere.cg"
#include "lighting.cg"
#include "fresnel.cg"

// Vertex to pixel shader structure
struct v2p
{
  float  extinction     : COLOR;
  float2 tc0            : TEXCOORD0;
  float3 Direction      : TEXCOORD1;
  float4 RayleighColor  : TEXCOORD2;
  float4 MieColor       : TEXCOORD3;
  float3 Position       : TEXCOORD4;    // For fragment shader
  float3 normal         : TEXCOORD5;
  // Fresnel in pixel shader
  float3 I              : TEXCOORD6;
  //float  fresnel        : TEXCOORD6;
  float3 R              : TEXCOORD7;    // Reflection vector
};

void main(
  // In
  in v2p IN,

  // Out
  out float4 outColor : COLOR,
  
  // Constants
  uniform sampler2D   baseMap : TEXUNIT0,
  uniform samplerCUBE envMap  : TEXUNIT1,
  uniform float3    lightDirection,
  uniform float3    lightColor,
  uniform float3    lightAmbient,
  uniform float3    eyePosW,
  uniform float     atmosRayleigh,
  uniform float     atmosMie,
  uniform float3    Ke,
  uniform float3    Ka,
  uniform float3    Kd,
  uniform float3    Ks,
  uniform float     Kr,
  uniform float3    shininess,
  uniform float     exposure
)
{
  float3 skyColor;

  float3 N=normalize(IN.normal);

  // Get sky gradient color
  skyColor.rgb=GetSkyColor(lightDirection,IN.Direction,IN.RayleighColor,IN.MieColor,atmosRayleigh,atmosMie,lightColor);

  // Get base texture color
  float4 baseCol=tex2D(baseMap,IN.tc0);

  // Reflection
  //const float Kr=0.5f;
  float4 envColor=texCUBE(envMap,IN.R);

  // Lighting
  float3 ambient,diffuse,specular;
  LightingSun(Ke,Ka,Kd,Ks,shininess,lightDirection,lightColor,lightAmbient,IN.Position,N,eyePosW,
    ambient,diffuse,specular);
  baseCol.rgb=baseCol*(ambient+Ke)+baseCol*diffuse*lightColor+specular;
  
  // Add reflection with fresnel
  float fresnel=Fresnel(0.15,0.85,2.0,normalize(IN.I),normalize(N));
  baseCol.rgb=FresnelMix(baseCol.rgb,envColor.rgb,Kr,fresnel);

  // HDR toning of sky
  //skyColor.rgb=1.0-exp(-exposure*skyColor.rgb);

  // Mix sky with texture color based on atmospheric influence
  outColor.rgb=lerp(skyColor,baseCol,IN.extinction);

  // Blending
  outColor.a=baseCol.a;
}
